Shareware Grab Bag/Shareware Grab Bag.iso/090/sampler4.arc/REGRESS.SAC

Text File | 1985-08-30 | 10KB | 324 lines

!*******************************************************************!
!                                                                   !
!               Single Equation Estimation Techniques               !
!                           (Chapter 9)                             !
!                                                                   !
!*******************************************************************!
ON ECHO

!    This example demonstrates estimation techniques available in
!    SORITEC Sampler.  Examples are taken from G.S. Maddala,
!    Econometrics, New York: McGraw-Hill, 1977.
!
!    The first example, which is taken from Maddala, p. 214-217
!    and p. 280-281, demonstrates the OLS, Cochrane-Orcutt
!    and Hildreth-Lu estimators.  The data are taken from J.C.G. Boot
!    and G.M. Dewit, "Investment Demand: An Empirical Contribution to
!    the Aggregation Problem", International Economic Review, 1960,
!    pp. 27-28.
!
!    Data can be read directly into SORITEC from a command file using
!    the READ command.  First define the observation period with the
!    USE command.
!

USE 1934 1954

!
!    When more than one variable is in the argument list, READ assigns
!    variables by columns.
!
!    Read in G.M. data
!

READ gm_investment gm_value gm_capital_stock
MISSING 3078.5  2.8
317.6   4661.7  52.6
391.8   5387.1  156.9
410.6   2792.2  209.2
257.7   4313.2  203.4
330.8   4643.9  207.2
461.2   4551.2  255.2
512.0   3244.1  303.7
448.0   4053.7  264.1
499.6   4379.3  201.6
547.5   4840.9  265.0
561.2   4900.9  402.2
688.1   3526.5  761.5
568.9   3254.7  922.4
529.2   3700.2  1021.1
555.1   3755.6  1099.0
642.9   4833.0  1207.7
755.9   4924.9  1430.5
891.2   6241.7  1777.3
1304.4  5593.6  2226.3
1486.7  MISSING MISSING
;

!
!    Read in G.E. data
!

READ ge_investment ge_value ge_capital_stock
MISSING 1170.6   97.8
 33.1   2015.8  104.4
 45.0   2803.3  118.0
 77.2   2039.7  156.2
 44.6   2256.2  172.6
 48.1   2132.2  186.6
 74.4   1834.1  220.9
113.0   1588.0  287.8
 91.9   1749.4  319.9
 61.3   1687.2  321.3
 56.8   2007.7  319.6
 93.6   2208.3  346.0
159.9   1656.7  456.4
147.2   1604.4  543.4
146.3   1431.8  618.3
 98.3   1610.5  647.4
 93.5   1819.4  671.3
135.2   2079.7  726.1
157.3   2371.6  800.3
179.5   2759.9  888.9
189.6   MISSING MISSING
;

!
!    Read in Westinghouse data
!

READ west_investment west_value west_capital_stock
MISSING   191.5      1.8
12.93     516.0       .8
25.90     729.0      7.4
35.05     560.4     18.1
22.89     519.9     23.5
18.84     628.5     26.5
28.57     537.1     36.2
48.51     561.2     60.8
43.34     617.2     84.4
37.02     626.7     91.2
37.81     737.2     92.4
39.27     760.5     86.0
53.46     581.4    111.1
55.56     662.3    130.6
49.56     583.8    141.8
32.04     635.2    136.7
32.24     723.8    129.7
54.38     864.1    145.5
71.78    1193.5    174.8
90.08    1188.9    213.5
68.60    MISSING   MISSING
;
END

!
!    Linear estimation of investment against value of the firm and
!    capital stock, both lagged by one year is simple since lags
!    can be specified directly in the command line.  First, change
!    the USE period to account for the lagged variables:
!

USE 1935 1954

!*******************************************************************!
!                                                                   !
!             Ordinary Least Squares Estimation                     !
!                       (Section 9.1)                               !
!                                                                   !
!*******************************************************************!

!
!    The OLS estimator is invoked by the REGRESS command:
!

REGRESS gm_investment gm_value(-1) gm_capital_stock(-1)

!
!    If you want to examine Beta coefficients and elasticities
!    associated with the coefficient estimates in OFF CRT mode,
!    set the ON BETA flag, ie.
!

ON BETA

REGRESS ge_investment ge_value(-1) ge_capital_stock(-1)

!
!    To plot actual versus fitted residuals, in addition to getting
!    beta coefficients and elasticities, set the ON PLOT option.
!

ON PLOT

!
!    Constraining the constant term to zero is enabled by including
!    the ORIGIN argument in the REGRESS command, i.e.,
!

REGRESS(ORIGIN) west_investment west_value(-1) west_capital_stock(-1)

!
!    Remember you must explicitly disable global options you no longer need.
!

OFF BETA
OFF PLOT

cls
!*******************************************************************!
!                                                                   !
!             Cochran-Orcutt Iterative Technique                    !
!                       (Section 9.2.1)                             !
!                                                                   !
!*******************************************************************!

!
!    Cochrane-Orcutt and Hildreth-Lu estimators are used when residuals are
!    first-order autoregressive.  Command syntax is identical to OLS
!    estimation; only the command name is different.  The Cochrane-Orcutt
!    procedure is invoked by the command:
!

CORC gm_investment gm_value(-1) gm_capital_stock(-1)

cls
!*******************************************************************!
!                                                                   !
!                 Hildruth-Lu Scanning Technique                    !
!                       (Section 9.2.2)                             !
!                                                                   !
!*******************************************************************!

!
!    The Hildreth-Lu iterative procedure is invoked by the HILU
!    command.  There are one keyword and three optional positional
!    parameters that may be entered in the command line for constraining
!    the fitted equation through the origin, defining lower and upper limits
!    to RHO and defining the stepsize.  When the latter three arguments
!    are omitted, they are assigned the initial values 0.0, 1.0 and
!    0.1, respectively.  In this example, we use the default values for
!    the lower and upper limits to RHO but redefine the stepsize to .05.
!    Note that the first two positional parameters are assigned their
!    default values by entering asterisks (*) in their respective
!    positions.
!

HILU(* * .05) ge_investment ge_value(-1) ge_capital_stock(-1)

cls
!*******************************************************************!
!                                                                   !
!               Two-Stage Least Squares Estimation                  !
!                         (Section 9.3)                             !
!                                                                   !
!*******************************************************************!

!
!    Single equation estimation of a structural equation belonging
!    to a general interdependent system of equations in SORITEC Sampler
!    uses the two-stage least squares (2SLS) estimator, and is
!    illustrated in the estimation of Klein's Model I. (See L.R. Klein,
!    "Economic Fluctuations in the United States 1921-41," New York:
!    John Wiley & Sons. 1950.
!
!    Annual data for consumption, profits, private wage bill, investment,
!    capital stock, government wage bill, government expenditures and
!    taxes are imported to SORITEC Sampler through the READ command.
!

USE 1920 1941
READ consumption profits private_wages investment capital_stock &
     government_wages government_expenditures taxes
    39.8 12.7 28.8  2.7 182.8   2.2  2.4  3.4
    41.9 12.4 25.5 -0.2 182.6   2.7  3.9  7.7
    45.0 16.9 29.3  1.9 184.5   2.9  3.2  3.9
    49.2 18.4 34.1  5.2 189.7   2.9  2.8  4.7
    50.6 19.4 33.9  3.0 192.7   3.1  3.5  3.8
    52.6 20.1 35.4  5.1 197.8   3.2  3.3  5.5
    55.1 19.6 37.4  5.6 203.4   3.3  3.3  7.0
    56.2 19.8 37.9  4.2 207.6   3.6  4.0  6.7
    57.3 21.1 39.2  3.0 210.6   3.7  4.2  4.2
    57.8 21.7 41.3  5.1 215.7   4.0  4.1  4.0
    55.0 15.6 37.9  1.0 216.7   4.2  5.2  7.7
    50.9 11.4 34.5 -3.4 213.3   4.8  5.9  7.5
    45.6  7.0 29.0 -6.2 207.1   5.3  4.9  8.3
    46.5 11.2 28.5 -5.1 202.0   5.6  3.7  5.4
    48.7 12.3 30.6 -3.0 199.0   6.0  4.0  6.8
    51.3 14.0 33.2 -1.3 197.7   6.1  4.4  7.2
    57.7 17.6 36.8  2.1 199.8   7.4  2.9  8.3
    58.7 17.3 41.0  2.0 201.8   6.7  4.3  6.7
    57.5 15.3 38.2 -1.9 199.9   7.7  5.3  7.4
    61.6 19.0 41.6  1.3 201.2   7.8  6.6  8.9
    65.0 21.1 45.0  3.3 204.5   8.0  7.4  9.6
    69.7 23.5 53.3  4.9 MISSING 8.5 13.8 11.6
  ;
END

!
!    Define the identity income_net_of_taxes.
!

identity income_net_of_taxes &
    net_income = private_wages + government_wages + profits

compute income_net_of_taxes

!
!     Since SORITEC does not permit transformations in the estimation command
!     line, compute (1) the sum of net_income and taxes less government wages
!               and (2) the sum of private and government wages,
!     as simple transformations.
!

x = net_income + taxes - government_wages

total_wages = private_wages + government_wages

!
!     The model consists of a consumption function, an investment
!     function and a demand-for-labor function (expressed as the
!     private wage bill), specified as:
!
!     consumption = a0 + a1*profits + a2*(total_wages) + a3*profits(-1)
!
!     investment = b0 + b1*profits + b2*profits(-1) + b3*capital_stock(-1)
!
!     private_wages = c0 + c1*x + c2*x(-1) + c3*time
!

!
!    Change to USE period to the estimation period.
!

USE 1921 1941

!
!    A dummy time series is generated simply by entering the TIME command.
!

TIME time

!
!    The TWOSTAGE command requires exogenous variables to be explicitly
!    identified using the EXOGENOUS command.
!

EXOGENOUS government_expenditures taxes government_wages profits(-1) &
          capital_stock(-1) x(-1) time

!
!    Now simply estimate each equation of the model with the TWOSTAGE command.
!

TWOSTAGE consumption profits total_wages profits(-1)

TWOSTAGE investment profits profits(-1) capital_stock(-1)

TWOSTAGE private_wages x x(-1) time

!
!    That's it!
!
QUIT